module deferred

import common

test OnDemandLoad:
    let services = "test"

    spawn as p1
    spawn as p2

    send "create-identity Device1" to p1
    send "create-identity Device2" to p2
    send "start-server services $services" to p1
    send "start-server services $services" to p2
    expect from p1:
        /peer 1 addr ${p2.node.ip} 29665/
        /peer 1 id Device2/
    expect from p2:
        /peer 1 addr ${p1.node.ip} 29665/
        /peer 1 id Device1/

    with p1:
        send "store blob"
        send "test"
        send ""
        expect /store-done ($refpat)/ capture blob_ref

        send "store ondemand"
        send "12"
        send "$blob_ref"
        send ""
        expect /store-done ($refpat)/ capture ondemand_ref

        send "test-message-send 1 $ondemand_ref"
        expect /test-message-send done/
        with p2:
            expect /test-message-received ondemand [0-9]+ $ondemand_ref/
            expect /test-ondemand-received 0 [0-9]+ $blob_ref/

            send "load-type $ondemand_ref"
            expect /load-type ondemand/

            send "load-type $blob_ref"
            expect /load-type-failed/

            send "load-deferred 0"
            expect /load-deferred-done 0 blob [0-9]+/

            send "load-type $blob_ref"
            expect /load-type blob/