Version information from git

3 files changed, 53 insertions, 4 deletions

diff --git a/src/Main.hs b/src/Main.hs
index 404ecec..adb738e 100644
--- a/src/Main.hs
+++ b/src/Main.hs
@@ -26,9 +26,6 @@ import System.Posix.Process
 import System.Posix.Signals
 import System.Process
 
-import Paths_erebos_tester (version)
-import Data.Version (showVersion)
-
 import Config
 import GDB
 import Network
@@ -38,6 +35,7 @@ import Process
 import Run.Monad
 import Test
 import Util
+import Version
 
 withVar :: ExprType e => VarName -> e -> TestRun a -> TestRun a
 withVar name value = local (fmap $ \s -> s { tsVars = (name, SomeVarValue value) : tsVars s })
@@ -356,7 +354,7 @@ main = do
             where header = "Usage: erebos-tester [OPTION...]"
 
     when (optShowVersion opts) $ do
-        putStrLn $ "Erebos Tester version " <> showVersion version
+        putStrLn versionLine
         exitSuccess
 
     getPermissions (head $ words $ optDefaultTool $ optTest opts) >>= \perms -> do
diff --git a/src/Version.hs b/src/Version.hs
new file mode 100644
index 0000000..ace016b
--- /dev/null
+++ b/src/Version.hs
@@ -0,0 +1,19 @@
+{-# LANGUAGE TemplateHaskell #-}
+
+module Version (
+    versionLine,
+) where
+
+import Paths_erebos_tester (version)
+import Data.Version (showVersion)
+import Version.Git
+
+{-# NOINLINE versionLine #-}
+versionLine :: String
+versionLine = do
+    let ver = case $$tGitVersion of
+            Just gver
+                | 'v':v <- gver, not $ all (`elem` ('.': ['0'..'9'])) v
+                -> "git " <> gver
+            _   -> "version " <> showVersion version
+     in "Erebos Tester " <> ver
diff --git a/src/Version/Git.hs b/src/Version/Git.hs
new file mode 100644
index 0000000..fcd54a0
--- /dev/null
+++ b/src/Version/Git.hs
@@ -0,0 +1,32 @@
+module Version.Git (
+    tGitVersion,
+) where
+
+import Language.Haskell.TH
+import Language.Haskell.TH.Syntax
+import Language.Haskell.TH.Syntax.Compat
+
+import System.Directory
+import System.Exit
+import System.Process
+
+tGitVersion :: SpliceQ (Maybe String)
+tGitVersion = unsafeSpliceCoerce $ do
+    let git args = do
+            (ExitSuccess, out, _) <- readCreateProcessWithExitCode
+                (proc "git" $ [ "--git-dir=./.git", "--work-tree=." ] ++ args) ""
+            return $ lines out
+
+    mbver <- runIO $ do
+        doesPathExist "./.git" >>= \case
+            False -> return Nothing
+            True -> do
+                desc:_ <- git [ "describe", "--always", "--dirty= (dirty)" ]
+                files <- git [ "ls-files" ]
+                return $ Just (desc, files)
+
+    case mbver of
+        Just (_, files) -> mapM_ addDependentFile files
+        Nothing -> return ()
+
+    lift (fst <$> mbver :: Maybe String)