19 files changed, 401 insertions, 0 deletions
diff --git a/test/asset/definition/basic.et b/test/asset/definition/basic.et
new file mode 100644
index 0000000..6ae248e
--- /dev/null
+++ b/test/asset/definition/basic.et
@@ -0,0 +1,22 @@
+def expr_def = 4
+
+def fun_expr_def (x) = x + 5
+
+def test_def (n):
+    shell as p on n:
+	echo $expr_def
+
+    expect from p:
+	/4/
+
+def fun_test_def (n) first x:
+    shell as p on n:
+	echo ${expr_def + x}
+
+    expect from p:
+	/${4 + x}/
+
+test Test:
+    node n
+    test_def (n)
+    fun_test_def (n) first 7
diff --git a/test/asset/expansion.et b/test/asset/expansion.et
new file mode 100644
index 0000000..d14f9a1
--- /dev/null
+++ b/test/asset/expansion.et
@@ -0,0 +1,18 @@
+def integer_var = 1
+def number_var = 1.3
+def string_var = "abc"
+def regex_var = /a.c/
+
+test VariableExpansion:
+    node n
+    shell as p on n:
+        echo "$integer_var"
+        echo "$number_var"
+        echo "$string_var"
+        echo "$string_var"
+
+    expect from p:
+        /$integer_var/
+        /$number_var/
+        /$string_var/
+        /$regex_var/
diff --git a/test/asset/parser/indent.et b/test/asset/parser/indent.et
new file mode 100644
index 0000000..01c4dd8
--- /dev/null
+++ b/test/asset/parser/indent.et
@@ -0,0 +1,41 @@
+def x1s:
+ wait
+
+def x2s:
+  wait
+
+def x4s:
+    wait
+
+def x8s:
+        wait
+
+def x16s:
+                wait
+
+def x1t:
+	wait
+
+def x2t:
+		wait
+
+export def e1s:
+ wait
+
+export def e2s:
+  wait
+
+export def e4s:
+    wait
+
+export def e8s:
+        wait
+
+export def e16s:
+                wait
+
+export def e1t:
+	wait
+
+export def e2t:
+		wait
diff --git a/test/asset/run-fail/bool.et b/test/asset/run-fail/bool.et
new file mode 100644
index 0000000..1608a08
--- /dev/null
+++ b/test/asset/run-fail/bool.et
@@ -0,0 +1,3 @@
+test Test:
+    node n
+    guard (True == False)
diff --git a/test/asset/run-success/bool.et b/test/asset/run-success/bool.et
new file mode 100644
index 0000000..7121cc0
--- /dev/null
+++ b/test/asset/run-success/bool.et
@@ -0,0 +1,7 @@
+test Test:
+    node n
+    guard (True == True)
+    guard (False == False)
+    guard (False /= True)
+    guard ((1 == 1) == True)
+    guard ((1 == 0) == False)
diff --git a/test/asset/run/echo.et b/test/asset/run/echo.et
new file mode 100644
index 0000000..9950d7b
--- /dev/null
+++ b/test/asset/run/echo.et
@@ -0,0 +1,4 @@
+test ExpectEcho:
+    spawn as p
+    send "abcdef" to p
+    expect /abcdef/ from p
diff --git a/test/asset/run/erebos-tester.yaml b/test/asset/run/erebos-tester.yaml
new file mode 100644
index 0000000..937ca97
--- /dev/null
+++ b/test/asset/run/erebos-tester.yaml
@@ -0,0 +1,2 @@
+tests: ./scripts/**/*.et
+tool: ./tools/tool
diff --git a/test/asset/run/sysinfo.et b/test/asset/run/sysinfo.et
new file mode 100644
index 0000000..1b9f6aa
--- /dev/null
+++ b/test/asset/run/sysinfo.et
@@ -0,0 +1,12 @@
+test SysInfo:
+    node n
+    spawn on n as p1
+    with p1:
+        send "network-info"
+        expect /ip ${n.ifname} ${n.ip}/
+
+    spawn as p2
+    guard (p2.node.ip /= p1.node.ip)
+    with p2:
+        send "network-info"
+        expect /ip ${n.ifname} ${p2.node.ip}/
diff --git a/test/asset/run/tools/echo.sh b/test/asset/run/tools/echo.sh
new file mode 100755
index 0000000..53b1eae
--- /dev/null
+++ b/test/asset/run/tools/echo.sh
@@ -0,0 +1,2 @@
+#!/bin/sh
+cat
diff --git a/test/asset/run/tools/sysinfo.sh b/test/asset/run/tools/sysinfo.sh
new file mode 100755
index 0000000..38591f4
--- /dev/null
+++ b/test/asset/run/tools/sysinfo.sh
@@ -0,0 +1,9 @@
+#!/bin/sh
+
+while read cmd; do
+    case "$cmd" in
+        network-info)
+            ip -o addr show | sed -e 's/[0-9]*: \([a-z0-9]*\).*inet6\? \([0-9a-f:.]*\).*/ip \1 \2/'
+            ;;
+    esac
+done
diff --git a/test/asset/run/trivial.et b/test/asset/run/trivial.et
new file mode 100644
index 0000000..0b2e878
--- /dev/null
+++ b/test/asset/run/trivial.et
@@ -0,0 +1,7 @@
+test AlwaysSucceeds:
+    node n
+    guard (1 == 1)
+
+test AlwaysFails:
+    node n
+    guard (1 == 0)
diff --git a/test/asset/shell/echo.et b/test/asset/shell/echo.et
new file mode 100644
index 0000000..1e48cac
--- /dev/null
+++ b/test/asset/shell/echo.et
@@ -0,0 +1,25 @@
+test Echo:
+    node n
+    let echo_str = "echo"
+    let space_str = "a   b"
+
+    shell on n as sh:
+        echo a b  c
+        echo "a b  c"
+        echo 'a b  d'
+        echo a b   " c  d"
+
+        /bin/echo "abcd"  xyz
+        "echo" a"a" "b"c   d
+        $echo_str b $echo_str c
+
+        echo "$space_str"
+        echo $space_str
+        echo '$space_str'
+
+        echo \$ \" \\
+        echo "\""\""a"
+        echo "'" '"' '\\\' "\\"
+        echo a\ b\ \ c
+
+        echo \" \' \\ \$ \# \| \> \< \; \[ \] \{ \} \( \) \* \? \~ \& \!
diff --git a/test/asset/shell/pipe.et b/test/asset/shell/pipe.et
new file mode 100644
index 0000000..64dcb07
--- /dev/null
+++ b/test/asset/shell/pipe.et
@@ -0,0 +1,5 @@
+test Pipe:
+    node n
+    shell on n as sh:
+        echo abcd | grep -o '[bc]*'
+        echo abcd | grep -o '[bcd]*' | grep -o '[ab]*'
diff --git a/test/asset/shell/spawn.et b/test/asset/shell/spawn.et
new file mode 100644
index 0000000..9d48e72
--- /dev/null
+++ b/test/asset/shell/spawn.et
@@ -0,0 +1,13 @@
+test ShellTrue:
+    node n
+    shell on n:
+        true
+
+    shell on n as sh:
+        true
+
+
+test ShellFalse:
+    node n
+    shell on n as sh:
+        false
diff --git a/test/script/definition.et b/test/script/definition.et
new file mode 100644
index 0000000..d2da737
--- /dev/null
+++ b/test/script/definition.et
@@ -0,0 +1,18 @@
+module definition
+
+asset scripts:
+    path: ../asset/definition
+
+test Definition:
+    spawn as p 
+    with p:
+        send "load ${scripts.path}/basic.et"
+        expect /load-done/
+
+        send "run Test"
+        expect /child-stdout p 4/
+        expect /match p 4/
+        expect /child-stdout p 11/
+        expect /match p 11/
+        expect /(.*)/ capture done
+        guard (done == "run-done")
diff --git a/test/script/expansion.et b/test/script/expansion.et
new file mode 100644
index 0000000..86a81dc
--- /dev/null
+++ b/test/script/expansion.et
@@ -0,0 +1,15 @@
+module expansion
+
+asset expansion:
+    path: ../asset/expansion.et
+
+test VariableExpansion:
+    spawn as p
+    with p:
+        send "load ${expansion.path}"
+        expect /load-done/
+        send "run VariableExpansion"
+        for str in [ "1", "1.3", "abc", "abc" ]:
+            expect /child-stdout p $str/
+            expect /match p $str/
+        expect /run-done/
diff --git a/test/script/parser.et b/test/script/parser.et
new file mode 100644
index 0000000..554e345
--- /dev/null
+++ b/test/script/parser.et
@@ -0,0 +1,13 @@
+module parser
+
+asset scripts:
+    path: ../asset/parser
+
+test Parser:
+    spawn as p 
+    with p:
+        send "load non-existing-file.et"
+        expect /load-failed file-not-found .*/
+
+        send "load ${scripts.path}/indent.et"
+        expect /load-done/
diff --git a/test/script/run.et b/test/script/run.et
new file mode 100644
index 0000000..7cc1670
--- /dev/null
+++ b/test/script/run.et
@@ -0,0 +1,105 @@
+module run
+
+asset scripts:
+    path: ../asset/run
+
+asset scripts_success:
+    path: ../asset/run-success
+
+asset scripts_fail:
+    path: ../asset/run-fail
+
+
+test TrivialRun:
+    spawn as p 
+    with p:
+        send "load ${scripts.path}/trivial.et"
+        expect /load-done/
+
+        send "run AlwaysSucceeds"
+        local:
+            expect /(run-.*)/ capture done
+            guard (done == "run-done")
+
+        send "run AlwaysFails"
+        local:
+            expect /match-fail .*/
+            expect /(run-.*)/ capture done
+            guard (done == "run-failed")
+
+
+test SimpleRun:
+    let should_succeed = [ "bool" ]
+    let should_fail = [ "bool" ]
+    spawn as p
+
+    with p:
+        for file in should_succeed:
+            send "load ${scripts_success.path}/$file.et"
+            local:
+                expect /(load-.*)/ capture done
+                guard (done == "load-done")
+            flush
+
+            send "run Test"
+            local:
+                expect /(run-.*)/ capture done
+                guard (done == "run-done")
+            flush
+
+        for file in should_fail:
+            send "load ${scripts_fail.path}/$file.et"
+            local:
+                expect /(load-.*)/ capture done
+                guard (done == "load-done")
+            flush
+
+            send "run Test"
+            local:
+                expect /(run-.*)/ capture done
+                guard (done == "run-failed")
+            flush
+
+
+test RunConfig:
+    node n
+    shell on n:
+        cp ${scripts.path}/erebos-tester.yaml .
+        mkdir tools
+        cp ${scripts.path}/tools/echo.sh ./tools/tool
+        mkdir scripts
+        # TODO: it seems that namespaces are not properly cleaned up after the failed test
+        #cp ${scripts.path}/trivial.et ./scripts/
+        cp ${scripts.path}/echo.et ./scripts/
+
+    spawn as p on n
+
+    with p:
+        send "load-config"
+        expect /load-config-done/
+        send "run-all"
+        #expect /run-test-result AlwaysSucceeds done/
+        #expect /run-test-result AlwaysFails failed/
+        expect /child-stdin p abcdef/
+        expect /child-stdout p abcdef/
+        expect /match p abcdef/
+        expect /run-test-result ExpectEcho done/
+        expect /run-all-done/
+
+
+test GetSysInfo:
+    node n
+    shell on n:
+        cp ${scripts.path}/erebos-tester.yaml .
+        mkdir tools
+        cp ${scripts.path}/tools/sysinfo.sh ./tools/tool
+        mkdir scripts
+        cp ${scripts.path}/sysinfo.et ./scripts/
+
+    spawn as p on n
+
+    with p:
+        send "load-config"
+        expect /load-config-done/
+        send "run SysInfo"
+        expect /run-done/
diff --git a/test/script/shell.et b/test/script/shell.et
new file mode 100644
index 0000000..2fe4ec3
--- /dev/null
+++ b/test/script/shell.et
@@ -0,0 +1,80 @@
+asset scripts:
+    path: ../asset/shell
+
+
+test ShellSpawn:
+    spawn as p
+    with p:
+        send "load ${scripts.path}/spawn.et"
+        local:
+            expect /(load-.*)/ capture done
+            guard (done == "load-done")
+        flush
+
+        send "run-all"
+        expect /run-test-result ShellTrue done/
+        expect /child-fail sh failed at: .*: false/
+        expect /child-fail sh exit code: 1/
+        expect /run-test-result ShellFalse failed/
+        expect /run-all-done/
+
+
+def expect_next_stdout from p (expected):
+    expect from p /child-stdout sh (.*)/ capture line
+    guard (line == expected)
+
+test ShellEcho:
+    spawn as p
+    with p:
+        send "load ${scripts.path}/echo.et"
+        local:
+            expect /(load-.*)/ capture done
+            guard (done == "load-done")
+        flush
+
+        send "run-all"
+
+    expect_next_stdout from p:
+        "a b c"
+        "a b  c"
+        "a b  d"
+        "a b  c  d"
+
+        "abcd xyz"
+        "aa bc d"
+        "b echo c"
+
+        "a   b"
+        "a   b"
+        "\$space_str"
+
+        "\$ \" \\"
+        "\"\"a"
+        "' \" \\\\\\ \\"
+        "a b  c"
+
+        "\" ' \\ \$ # | > < ; [ ] { } ( ) * ? ~ & !"
+
+    with p:
+        expect /run-test-result Echo done/
+        expect /run-all-done/
+
+
+test ShellPipe:
+    spawn as p
+    with p:
+        send "load ${scripts.path}/pipe.et"
+        local:
+            expect /(load-.*)/ capture done
+            guard (done == "load-done")
+        flush
+
+        send "run-all"
+
+    expect_next_stdout from p:
+        "bc"
+        "b"
+
+    with p:
+        expect /run-test-result Pipe done/
+        expect /run-all-done/